* -----------------------------------------------------------------
* SPSS Relig92P sp2 - For ASR 1997 MS
* -----------------------------------------------------------------
*
* (c) Copyright 1995-1997 by Jonathan Kelley and Nan Dirk De Graaf.
* Permission to use this SPSS, and the data file it creates, for
* non-commercial purposes is freely granted, PROVIDED that use is
* acknowledged by a bibliographic citation to:
* Kelley, Jonathan and Nan Dirk De Graaf. 1997. "National Context,
* Parental Socialization, and Religious Belief: Results from 15 Nations"
* American Sociological Review 62 (August):639-659.
*
* WHAT THIS FILE DOES:
* (1) This file begins with the raw data from the International
* Social Survey Program's "Religion" module! (The variables needed,
* together with some others that might allow useful parallel analyses on
* related topics are in file GOD3; the full ISSP data file is available
* from data archives throughout the world -- look on the internet for
* details at www.issp.org)! This SPSS makes all the variables used
* in our analysis for our ASR 197 paper "National context, parental
* socialization, and religious belief" It would be easy to extend this
* SPSS to prepare other variables for analysis (either those in the
* small file GOD3 for in the original full ISSP data set -- the SPSS
* will work with either)
*
* (2) The variables used in our ASR paper are then saved in file WORK3! This
* file would be a convenient starting place for further analyses on the
* issues raised in the paper, or for analyses on a number of related topics!
*
* (3) The full set of analysis runs (and some additional analyses not used
* in the published paper) are at the end! They can be run either in the
* full sequence beginning with the raw data (in file GOD3 or the original
* ISSP data) or, alternatively, directly from the file WORK3)!
*
* A NOTE ON STYLE: We have heavily commented the SPSS for clarity! The
* SPSS is set up for SPSS for Windows and should run 'out of the box'
* after you change the the two 'GET FILE' statements to reflect where
* you have put the data files on your computer! All statements end with
* a period (which is why comments use the exclamation point rather than
* a period); this is right for PC systems but may need changing on UNIX
* systems -- thats not hard and we have run it on both systems!
*
* REQUESTS:
* (1) We have tried to be very careful to catch programming errors,
* but there is still a real risk of error in any large program! If you find
* any errors, please let us know (we and others are building on this SPSS
* for further work)!
*
* (2) If you develop any good SPSS for this data set that you would
* be willing to share (careful, well documented, and potentially
* interesting to others) please send it to us and we will, if we like it,
* include it in the public version! Useful possibilities include:
* characteristics of denominations -- for example theology, size, wealth;
* characteristics of nations in addition to those we have coded (but be
* careful: with only 18, mostly developed nations, there are real limits
* to what can sensibly be done)!
*
* E-MAIL: kelley@international-survey.org n.degraaf@mailbo.kun.nl
TITLE ISSP 92: Religious mobility MS .
* File: Relig92p SP2
12 August 1997
* NOTES to ourselves:
DATA: New data from Z-A (from the 1988-1992 ZA cd-rom), God3 SAV, 1997
--- May 1996: All for ASR God MS with Nan Dirk (1st ASR version)
--- Versions k, l & m, January 1997: final ASR, at Nijmegen
--- Version O: Check all for ASR
--- Version P: Add newest GNP data; & re-run all for ASR;
.
*--- OMITTING Philippines (errors in ZA version), Israel (Jewish & error
in MoChAtt), and Russia (no ChAtt)!.
* on Nan Dirk's machine: .
*GET FILE='c:\My Documents\ASR\data\God3.sav'.
* on Kelley's machine:.
GET FILE='k:\val\god.ASR\DATA\GOD3.$W'.
*------------------------------- This made the files (from cd-rom).
*IMPORT FILE='d:\DATA\s2150.por'.
**Omit Russia, Israel, Philippines .
*SELECT IF ( v3 NE 14 and v3 NE 17 and v3 NE 15 ).
*SAVE OUTFILE='K:\val\god\DATA\GOD3.$W'
/KEEP= v2 v3 v5 v6 v9 v10 v12 v13 v14 v15 v16 v17 v31 v32 v33 v34
v35 v36 v37 v39 v40 v50 v51 v52 v53 v54 v55 v56 v57 v59 v61 v62 v65
v77 v78 v79 v81 v98 v99 v106 v107 v121 v127 v128 .
*FREQUENCIES VARIABLES=
v3 v5 v6 v9 v10 v12 v13 v14 v15 v16 v17 v31 v32 v33 v34
v35 v36 v37 v39 v40 v50 v51 v52 v53 v54 v55 v56 v57 v59 v61 v62 v65
v77 v78 v79 v81 v98 v99 v106 v107 v121 v127 v128 .
** ------------------------- end of SPSS making the data files .
SET WIDTH= 80.
* @>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>> Demographics
VARS: Age Male EducYr
Country GermWest GermEast GB NIreland USA Hungary
Netherl Italy Ireland Norway Austria Slovenia Poland NZ Phil Oz
.
COMPUTE Country = v3 .
VARIABLE LABELS Country "Nation".
VALUE LABELS Country
01 'Germany-West ================'
02 'Germany-East ================'
03 'Great Britain ================'
04 'N Ireland ================'
05 'USA ================'
06 'Hungary ================'
07 'Netherlands ================'
08 'Italy ================'
09 'Ireland================'
10 'Norway ================'
11 'Austria ================'
12 'Slovenia ================'
13 'Poland ================'
14 'Israel ================'
15 'Philippines ================'
16 'New Zealand ================'
17 'Russia ================'
18 'Australia ================'
.
COMPUTE AngloC = Country .
RECODE AngloC (3 4 5 9 16 18 =1)(ELSE=0).
VARIABLE LABEL AngloC "Anglo-Celtic nations".
RECODE Country ( 1=1)(ELSE=0) INTO GermWest .
RECODE Country ( 2=1)(ELSE=0) INTO GermEast.
RECODE Country ( 3=1)(ELSE=0) INTO GB.
RECODE Country ( 4=1)(ELSE=0) INTO NIreland .
RECODE Country ( 5=1)(ELSE=0) INTO USA .
RECODE Country ( 6=1)(ELSE=0) INTO Hungary .
RECODE Country ( 7=1)(ELSE=0) INTO Netherl .
RECODE Country ( 8=1)(ELSE=0) INTO Italy .
RECODE Country ( 9=1)(ELSE=0) INTO Ireland .
RECODE Country (10=1)(ELSE=0) INTO Norway .
RECODE Country (11=1)(ELSE=0) INTO Austria .
RECODE Country (12=1)(ELSE=0) INTO Slovenia .
RECODE Country (13=1)(ELSE=0) INTO Poland .
RECODE Country (14=1)(ELSE=0) INTO Israel .
RECODE Country (15=1)(ELSE=0) INTO Phil .
RECODE Country (16=1)(ELSE=0) INTO NZ .
RECODE Country (17=1)(ELSE=0) INTO Russia .
RECODE Country (18=1)(ELSE=0) INTO Oz .
VALUE LABELS GermWest GermEast GB NIreland USA Hungary
Netherl Italy Ireland Norway Austria Slovenia Poland NZ Phil Oz
1 "Yes" 0 "No".
* ----- Age, year born, cohort.
COMPUTE Age = v78 .
RECODE Age (LOWEST THRU 14, 99=SYSMIS).
COMPUTE YearBorn = 1991 - Age .
* ------------- Sex.
RECODE V77 (1=1)(2=0)(ELSE=SYSMIS) INTO Male .
* -------------- Education
.
COMPUTE EducYr = v98.
RECODE EducYr ( 0 THRU 8= 8)(20 THRU 25=20)(26 thru HIGHEST= SYSMIS) .
* ---- Error check.
*FREQUENCIES VARIABLES= AngloC Country EducYr v98 Age v78 .
*MEANS TABLES= AngloC BY Country / EducYr BY v98 .
*SPLIT FILE BY Country.
*FREQUENCIES VARIABLES= v5 v6 v9 v10 v12 v13 v14 v15 v16 v17 v31 v32 v33 v34
v35 v36 v37 v39 v40 v50 v51 v52 v53 v54 v55 v56 v57 v59 v61 v62 v65
v77 v78 v79 v81 v98 v99 v106 v107 v121 v127 v128 .
*SPLIT FILE OFF.
* @>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>> Denomination, Church Attendance
* --------------------------------------- Denomination
* MoAthst MoCath MoProt MoNonCr FaAthst FaCath FaProt FaNonCr
* SpAthst SpCath SpProt Athst Cath Prot
.
RECODE V50 (1=1)(96 97 98 99=SYSMIS)(ELSE=0) INTO MoAthst .
RECODE V50 (3=1)(96 97 98 99=SYSMIS)(ELSE=0) INTO MoCath .
RECODE V50 (1 3 9 10 11 12 13 14 =0)(96 97 98 99=SYSMIS)(ELSE=1) INTO MoProt .
RECODE V50 (8 THRU 14=1)(ELSE=0) INTO MoNonCr .
RECODE V51 (1=1)(96 97 98 99=SYSMIS)(ELSE=0) INTO FaAthst .
RECODE V51 (3=1)(96 97 98 99=SYSMIS)(ELSE=0) INTO FaCath .
RECODE V51 (1 3 9 10 11 12 13 14 =0)(96 97 98 99=SYSMIS)(ELSE=1) INTO FaProt .
RECODE V51 (8 THRU 14=1)(ELSE=0) INTO FaNonCr .
RECODE V52 (1=1)(96 97 98 99 0 =SYSMIS)(ELSE=0) INTO SpAthst .
RECODE V52 (3=1)(96 97 98 99 0 =SYSMIS)(ELSE=0) INTO SpCath .
RECODE V52 (1 3 9 10 11 12 13 14 =0)(96 97 98 99 0=SYSMIS)(ELSE=1) INTO SpProt.
RECODE V106 (90=1)(97 98 99=SYSMIS)(ELSE=0) INTO Athst .
RECODE V106 (10=1)(97 98 99=SYSMIS)(ELSE=0) INTO Cath .
RECODE V106 (10 90 20 30 51 52 53 93=0)(97 98 99=SYSMIS)(ELSE=1) INTO Prot .
* ----------- Combined parent version, for simplicity!
* mfCath mfAthst mfProt mfNonCr .
COMPUTE mfNonCr = MEAN( MoNonCr,FaNonCr).
COMPUTE mfCath = MEAN( MoCath, FaCath ).
COMPUTE mfAthst = MEAN( MoAthst, FaAthst ).
COMPUTE mfProt = MEAN( MoProt, FaProt ).
* --------------------------------------- Church attendance: mo, fa, r at 12
MoChAtt FaChAtt ChAtt12 mfChAtt
.
COMPUTE MoChAtt = v54.
COMPUTE FaChAtt = v55.
COMPUTE ChAtt12 = v56.
VARIABLE LABELS
MoChAtt "Mothers church attendence"
FaChAtt "Fathers church attendence"
ChAtt12 "Church attend: R age 11 or 12"
.
* ----- Days per year coding.
RECODE FaChAtt MoChAtt ChAtt12 ( 1 2 3=1)(4=3)(5=12)(6=24)(7=36)
(8 9 10 11 =52) (ELSE= SYSMIS) .
IF (MOATHST EQ 1) MOCHATT= 1.
IF (FAATHST EQ 1) FACHATT= 1.
* average of mo & fa .
COMPUTE mfChAtt = MEAN( MoChAtt, FaChAtt ) .
* ----- Coding based on relation to belief in God .
* Category 1 is quite different in belief in god from 2 and 3 (which are
by no means identical themselves!), and so should be separated for tabular
and such analyses! Athiests (on the denomination Q) are very different too!
Combine (for Nan Dirk analysis) athiests with church attendance (little loss
empirically as some 95% of athiests never go to church, and were not even
asked the ChAtt Qs in a few nations)!
VARS: mfChAtt2 fChAtt2 mChAtt2 .
.
RECODE v54 ( 1=2)( 2 3=3)(4=4)(5=5)(6=6)(7=7)(8 9 10 11 =8)
(ELSE= SYSMIS) INTO mChAtt2 .
IF (MoAthst EQ 1) mChAtt2 = 1.
RECODE v55 ( 1=2)( 2 3=3)(4=4)(5=5)(6=6)(7=7)(8 9 10 11 =8)
(ELSE= SYSMIS) INTO fChAtt2 .
IF (FaAthst EQ 1) fChAtt2 = 1.
VARIABLE LABELS
mChAtt2 "Mothers church attend (athiest low)"
fChAtt2 "Fathers church attend (athiest low)".
COMPUTE mfChAtt2 = MEAN( fChAtt2 , mChAtt2 ).
VALUE LABELS mChAtt2 fChAtt2 mfChAtt2
1 "No religion" 2"Never attend" 3"About 1 per year"
4 "Several times a year" 5 "About once a month"
6 "2-3 times a month" 7 "Nearly every week" 8 "Every week or more" .
* ----------------- Version for dummy variables & tables.
* --- alternate version gets OK marginals at low end, although with a
* little loss! Probably better for dummy variable analysis .
RECODE mfChAtt2 (1.00 1.50 2.00= 1)( 2.50 3.00 = 2)
(3.50 4.00 4.50 5.00 =3)(5.50 6.00 6.50 7.00 7.50 =4)
(8.00 =5) INTO mfChAtt4 .
VARIABLE LABELS mfChAtt4 "Parents: Church attnd (tabular v2)".
VALUE LABELS mfChAtt4 1 "Never or athiest" 2 "1 or 2 per year"
3 "Up to 1 a month" 4 "Almost every week" 5 "Both go every week" .
* ---------------------------------- respondent church attendance
VARS: lnChAtt2 Chatt2 .
* FOR RESPONDENTS CHURCH ATTENDANCE (NOT PARENTS, NOT AT 12):
Austria & Slovenia did not ask church attendance! (Can still
use them for the ASR "god" MS, as R's church attendance is
not used in it! Note that one answer category is not used in
E&W Germany, and another in Netherlands! Probably best to ignore
that in recoding to #days per year! Category 0 used only in GB and
Nireland, seems to be athiests who were not asked ChAtt!
* Categories 5 and 6 are very different in mean belief in God, so
should be separated for tabular & such analysis! Include athiests there too!
* Little difference between ChAtt in 1-5 coding, # days/year coding,
and Ln #days -- surprisingly #days looks OK, possibly beter in correls,
although the NLR results may be more sensible and stable with either
of the other two (which are corr =96 in the pooled sample)! .
VALUE LABELS V107
0 "Not asked (GB,NI,A,SLO)"
1 "Once a week"
2 "2-3 times a month"
3 "Once a month (Not WG, EG)"
4 "Several times a year (not NL)"
5 "Less frequently"
6 "Never"
8 "Don't know"
9 "NA, refused"
.
* Beware Slovenia, Austria, Israel where Q not asked!.
DO IF (Country EQ 11 OR Country EQ 12 OR Country EQ 14).
RECODE V107 (0 THRU 9=SYSMIS)(ELSE=-1) INTO ChAttNow .
ELSE.
RECODE v107 (0, 6=1)( 4 5=2)(3=3)(2=4)( 1=5)(ELSE= SYSMIS) INTO ChAttNow .
END IF.
VARIABLE LABELS ChAttNow "Church attendance now (tabular)" .
VALUE LABELS CHATTNOW 1 "NEVER" 2"FEW TIMES A YEAR"
3 "ONCE A MONTH" 4 "ALMOST EVERY WEEK" 5 "WEEKLEY"
.
* 2-3 per month catgy lower in Germany, since no "monthly" offered? .Only
130 cases in WG and 50 in EG (with samples of 1500), so no big deal! .
DO IF (Country EQ 11 OR Country EQ 12).
RECODE V107 (0 THRU 9=SYSMIS)(ELSE=-1) INTO ChAtt2.
ELSE IF (Country LE 2).
RECODE V107 (1 = 52)(2=18)(3=-1)(4=3)(5=1)(0,6=0.5)(ELSE=SYSMIS) INTO ChAtt2.
ELSE.
RECODE V107 (1 = 52)(2=36)(3=12)(4=3)(5=1)(0,6=0.5)(ELSE=SYSMIS) INTO ChAtt2.
END IF.
* --- Log version.
COMPUTE lnChAtt2 = LN( Chatt2 ).
VARIABLE LABELS
ChAtt2 "Church attend now, # days"
LnChatt2 "ln church attend now, # days".
* --- error check.
*FREQUENCIES VARIABLES= LnChatt2 v107 ChAtt2 CHATTNOW mfChAtt4
mChAtt2 fChAtt2 mfChAtt2 /STATISTICS= MEANS STDDEVS.
*MEANS TABLES= LnChatt2 by ChAtt2
/CHATTNOW Chatt2 BY V107 Country /Chatt2 BY Country BY V107
/mfChAtt4 by mfChAtt2 /mChAtt2 BY V54 /fChAtt2 BY V55 .
* @>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>> Christian Belief
Scale looks good in pooled data, with God2 weakest; fine in each country
separately! Some worry with missing data on the 2nd and 3d item in Norway and
possibly other secular countries!
We tried adding Devil, Heaven, Hell, GodCares and Bible Qs! Seems that
inter-item correls are always high, but correls with other variables
are distinctive -- only GodCares improves matters (and its the weakest
of the 4 in the final scale)!
NOTE: There is a some processing error in the Philippines; (JK discussed
it with the Philippines group at ISSP and they say the corrls are OK in the
data they used in Philippines, wrong only in ISSP version! So we drop it
from the analysis unless we can get a corrected data set in time)!
VARS: God CloseGod God2 AftLife Devil Heaven Hell Bible GodCares
.
RECODE V31 (6=100)(5=80)(4=60)(3=40)(2=20)(1=0)(ELSE=SYSMIS) INTO God .
RECODE V32 (5=100)(4=75)(3=50)(2=25)(1=0)(ELSE=SYSMIS) INTO CloseGod .
RECODE V33 (4=100)(3=67)(2=33)(1=0)(ELSE=SYSMIS) INTO God2 .
VARIABLE LABELS God "v31: Believe God (usual ISSS Q)"
/CloseGod "v32: Close to God"
/God2 "v33: Belief in God (alt Q)"
.
RECODE V34 (1=100)(2=67)(3=33)(4=0)(ELSE=SYSMIS) INTO AftLife .
RECODE V35 (1=100)(2=67)(3=33)(4=0)(ELSE=SYSMIS) INTO Devil .
RECODE V36 (1=100)(2=67)(3=33)(4=0)(ELSE=SYSMIS) INTO Heaven .
RECODE V37 (1=100)(2=67)(3=33)(4=0)(ELSE=SYSMIS) INTO Hell .
RECODE V39 (1=100)(2=50)(3,4=0)(ELSE=SYSMIS) INTO Bible .
RECODE V40 (1=100)(2=75)(3=50)(4=25)(5=0)(ELSE=SYSMIS) INTO GodCares .
VARIABLE LABELS AftLife "V34 life after death?"
/Devil "V35 believe in the Devil?"
/Heaven "V36 believe in Heaven?"
/Hell "V37 believe in Hell?"
/Bible "V39 Bible word of God?"
/GodCares "V40 God concerns Himself with humans?" .
* === scale.
COMPUTE GodPsnl = MEAN( God, CloseGod, God2, GodCares ).
COMPUTE GodPsnl = RND( GodPsnl ).
* not for Philippines.
IF (Phil EQ 1) GodPsnl = $SYSMIS.
VARIABLE LABELS GodPsnl "Believe in personal God (scale)".
* ----- 5 category versions for diagonal reference models
Version 5c looks better than 5 or 5b to us.
RECODE Godpsnl (0 thru 19=1)(19 thru 47=2)(47 thru 74=3)(74 thru 88=4)
(88 thru 100=5) into GodPsn5 .
RECODE GodPsnl (0 THRU 31=1)(31 THRU 50=2)(50 THRU 70=3)(70 THRU 86=4)
(86 THRU 100=5) INTO GodPsn5b .
RECODE Godpsnl (0 thru 36=1)(36 thru 54=2)(54 thru 72=3)(72 thru 92=4)
(92 thru 100=5) into GodPsn5c .
VARIABLE LABELS
GodPsn5 "Own belief in god, 5 ctgy vsn A"
GodPsn5c "Own belief in god, 5 ctgy vsn C"
GodPsn5b "Own belief in god, 5 ctgy vsn B".
VALUE LABELS GodPsn5 GodPsn5b GodPsn5c 1"Secular person" 3 "Middle person"
5 "Devout person".
* --- Error checks.
*FREQUENCIES GodPsn5 GodPsn5b GodPsn5c GodPsnl God, CloseGod, God2, GodCares
/STATISTICS= MEANS STDDEVS.
*MEANS TABLES= GodPsn5 GodPsn5b BY GodPsnl
/AftLife BY V34 / GodCares BY V40 .
* @>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>> CONTEXTUAL VARS NEC:
ReligCC mfChAtCC CathCC CommstCC Relig2CC
.
* ----------------------- Country Size, weight
Total N is 17635; may want to weight so each nation has equal weight
and sum = that!
.
COMPUTE SizeCC = Country.
RECODE SizeCC (1= 1165 )(2= 1120 )(3= 1086 )(4= 764 )
(5= 1209 )(6= 967 )(7= 1526 )(8= 872 )(9= 997 )
(10= 1226 )(11= 905 )(12= 1924 )(13= 908 )(16= 907 )
(18= 2059 )(ELSE=-1).
COMPUTE EqualWt = ( 1 / SizeCC )* (17635 / 15) .
* --- error check:
**frequencies variables= country SizeCC EqualWt .
**means tables= EqualWt by country.
**weight by EqualWt .
**frequencies variables= country .
*-------------------------- Religious context: country wide mean on
* GodPsnl =Believe in personal God (VSN 2)
.
RECODE COUNTRY
(1 = 59 ) (2 = 27 ) (3 = 58 ) (4 = 82 ) (5 = 82 )
(6 = 54 ) (7 = 51 ) (8 = 73 ) (9 = 81 ) (10= 55 )
(11= 63 ) (12= 50 ) (13= 80 ) (16= 60 ) (18= 60 )
(ELSE= -1) INTO RELIGCC .
VARIABLE LABELS ReligCC "Mean relig in nation (GodPsnl, vsn 2)".
* ------ Five groups by GodPsnl, for alt diag ref model (appendix table a).
COMPUTE GodCC = Country .
RECODE GodCC (2 12 7 =1)(3 16 18 10 6=2)(1 11 =3)(8 5 =4)
(4 13 15 9 = 5)(else=-1).
VARIABLE LABELS GodCC "Religious belief of nation, 5 groups".
VALUE LABELS GodCC 1 "Secular nation" 3 "Middle nation"
5 "Religious nation".
* ---- Interaction with parents church attendance (days/year coding).
COMPUTE ChXRelCC = mfChAtt * ReligCC .
VARIABLE LABELS ChXRelCC "Interaction: mfChAtt * ReligCC of nation".
* ---- Interaction with parents church attendance (nominal coding,
* with athiest as lowest category).
COMPUTE C2XRelCC = mfChAtt2 * ReligCC .
VARIABLE LABELS C2XRelCC "Interaction: mfChAtt2 * ReligCC of nation".
* ----------------------- Parents church attendance (in days per year coding).
RECODE COUNTRY
( 1= 19.54)( 2= 9.19)( 3= 14.66)( 4= 32.84)( 5= 27.20)( 6= 22.80)
( 7= 26.77)( 8= 30.39)( 9= 48.22)(10= 7.44)(11= 25.76)(12= 24.97)
(13= 37.26)(15 = 37.29)(16= 15.26) (18= 16.68)(ELSE=SYSMIS) INTO mfChAtCC.
VARIABLE LABELS mfChAtCC "Country mean: Parents church attencance ".
* --- vsn with 5 groups for alt diag ref model (appendix table A).
COMPUTE PChAttCC = Country.
RECODE PChAttCC (2 10 = 1) (3 16 18 1 = 2)
(6 5 7 11 12 = 3) (4 8 13 = 4) (9 = 5) (ELSE=-1).
* ------------------- Context varibles.
RECODE Country (2 10 =1) (3 16 18 12 7 =2) (1 6 11 = 3)
(8 5 =4) (4 13 15 9 =5) (ELSE=SYSMIS) INTO Relig3CC .
VARIABLE LABEL Relig3CC "Nation: Belief + mfChatt (tabular)".
RECODE COUNTRY (2 10 =1) (3 16 18 12 6 7=2)(1 11 = 3)
(8 5 =4) (4 13 15 16 9 =5) (ELSE=SYSMIS) INTO RELIG4CC .
VARIABLE LABEL RELIG4CC "NATION:MFCHAT".
VALUE LABELS RELIG3CC RELIG4CC
1 "SECULAR NATION" 2 "MOSTLY SECULAR NATION"
3 "Middle nation" 4 "Mostly religious nation" 5 "Religious nation" .
* ------ INTERACTION FOR OLS .
COMPUTE RelXChAt = Relig4CC * mfChAtt4 .
VARIABLE LABELS RelXChAt "Interaction: Relig4CC * mfChAtt4 ".
* ------------------- Percent Catholic .
COMPUTE CathCC = COUNTRY .
RECODE CathCC (1= .4260 )(2= .0566 )(3= .1111 )(4= .3309 )
(5= .2644 )(6= .6945 )(7= .2207 )(8= .9308 )(9= .9303 )
(10= .0061 )(11= .8110 )(12= .8279 )(13= .9602 )(15= .8500 )
(16= .1357 ) (18= .21 ) .
VARIABLE LABELS CathCC "% Catholic in nation".
* ------------------- Formerly communist .
RECODE COUNTRY ( 02 06 12 13 17 =1)(ELSE= 0) INTO CommstCC .
VARIABLE LABELS CommstCC "Formerly communist country ".
* ------------------ GNP per capita at parity purchasing power
From World Bank, "From Plan to Market: World Development
Report 1996" table 1 for 1987 (ie pre-reform for communist nations) --
that will be closer to what it was like when Rs were growing up!
Some approximations: West & East Germany, NIre from 1992 source above;
.
RECODE Country
( 1 = 76)( 2 = 52)( 3 = 71)( 4 = 56)( 5 = 100)( 6 = 29)
( 7 = 70)( 8 = 71)( 9 = 41)( 10= 78)( 11= 73)( 12= 33)
(13= 21)( 14= 57)( 15= 10)( 16= 63)( 17= 31)( 18= 70) INTO GNP .
VARIABLE LABELS GNP "GNP/capita 1988 at PPP (US=100) World Bank 96".
* --- Error check.
*FREQUENCIES VARIABLES= GNP PChAttCC GodCC Country mfChAtCC RELIGCC
RELIG3CC RELIG4CC CathCC .
*MEANS TABLES= GNP BY Country
/PChAttCC by country mfChAtCC /GodCC by Country ReligCC
/RELIGCC mfChAtCC RELIG3CC RELIG4CC CathCC BY Country .
* >>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>> NEC
We adopt a new & better GNP measure; and the latest version of the
raw data!
*------- score covariates as deviations from the mean
!! USE THIS FOR DIAG REF MODEL, NOT NICE FOR OLS !!
.
COMPUTE GNP = GNP - 60.96 .
* Old version of gnp: COMPUTE GNP = GNP - 58.0764 .
COMPUTE EDUCYR = EDUCYR - 11.21 .
* old version: COMPUTE EDUCYR = EDUCYR - 11.2714 .
COMPUTE AGE = AGE - 44.62 .
* olf version: COMPUTE AGE = AGE - 44.1923 .
* ------------- selected dummys (FOR DIAG REF MODEL).
RECODE RELIG4CC (2=1)(ELSE=0) INTO ROW2 .
RECODE RELIG4CC (3=1)(ELSE=0) INTO ROW3 .
RECODE RELIG4CC (4=1)(ELSE=0) INTO Row4 .
RECODE RELIG4CC (5=1)(ELSE=0) INTO Row5 .
RECODE RELIG4CC (1=1)(ELSE=0) INTO Row1 .
RECODE RELIG4CC (4,5=1)(ELSE=0) INTO Row45 .
RECODE RELIG4CC (2,3=1)(ELSE=0) INTO Row23 .
* --------------- Count missing in model vars! (ASR "god" MS) .
COUNT Miss = GodPsnl RELIG4CC mfchatt4 Age male
CommstCC EducYr GNP mfCath (SYSMIS) .
* <<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<
*^@<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<
* END OF VARIABLE DEFINITION; ANALYSES FOLLOW.
* ----------------------------------------------------- GOD MS: ALL RUNS
(Runs of 25 May 1996 at Nijemegen; revised Jan 1997 at Nijmegen;
re-run with new GNP data & latest version of data June 1997 at Canberra)
.
* --------------------------------Text tables 1-3 for relgion MS .
TITLE ISSP 1992: Religious mobility MS (ALL cases).
SPLIT FILE OFF.
SUBTITLE Table 1 & Text re missing data (ALL CASES).
FREQUENCIES VARIABLES= God, God2, CloseGod, GodCares
v54 v55 V107 V106 V50 V51 .
MEANS TABLES= GodPsnl MoChAtt FaChAtt MFCHATT4 V107
Age male EducYr Athst Cath MFCATH BY Country .
**SPLIT FILE BY Country .
**FREQUENCIES VARIABLES= God, God2, CloseGod, GodCares
v54 v55 V107 V106 V50 V51 .
**MEANS TABLES= GodPsnl MoChAtt FaChAtt MFCHATT4 V107
Age male EducYr Athst Cath MFCATH BY Country .
**SPLIT FILE OFF.
* --- in TEXT: measurement issues .
SUBTITLE: Text re measurement issues .
RELIABILITY
/VARIABLES= God, God2, CloseGod, GodCares
/FORMAT=LABELS /SCALE(ALPHA)=ALL/MODEL=ALPHA.
SPLIT FILE BY Country .
RELIABILITY
/VARIABLES= God, God2, CloseGod, GodCares
/FORMAT=LABELS /SCALE(ALPHA)=ALL/MODEL=ALPHA.
SPLIT FILE OFF.
REGRESSION VARIABLES= MoChAtt FaChAtt MFCHATT4
/STATISTICS= R COEF /DESCRIPTIVES = DEFAULTS
/MISSING= PAIRWISE
/DEPENDENT= MFCHATT4
/ENTER= MoChAtt FaChAtt .
RELIABILITY
/VARIABLES= MoChAtt FaChAtt
/FORMAT=LABELS /SCALE(ALPHA)=ALL/MODEL=ALPHA.
SUBTITLE God MS: Table 1 .
FREQUENCIES VARIABLES= God, God2, CloseGod, GodCares
/STATISTICS=MEANS STDDEVS.
SUBTITLE God MS: Table 2.
FACTOR /VARIABLES = God, God2, CloseGod, GodCares
/MISSING LISTWISE /PRINT UNIVARIATE CORRELATION
/ANALYSIS = God, God2, CloseGod, GodCares
/PRINT EXTRACTION ROTATION /EXTRACTION PAF
/CRITERIA ITERATE(25) /ROTATE= VARIMAX .
SPLIT FILE BY Country .
FACTOR /VARIABLES = God, God2, CloseGod, GodCares
/MISSING LISTWISE /PRINT UNIVARIATE CORRELATION
/ANALYSIS = God, God2, CloseGod, GodCares
/PRINT EXTRACTION ROTATION /EXTRACTION PAF
/CRITERIA ITERATE(25) /ROTATE= VARIMAX .
SPLIT FILE OFF.
SUBTITLE God MS: Table 3.
MEANS TABLES= GodPsnl BY COUNTRY /GodPsnl BY ChAttNow
/ GodPsnl BY COUNTRY BY ChAttNow .
SUBTITLE God MS: Table 5 (or 4, if rearrange).
MEANS TABLES= GodPsnl BY MFCHATT4 by RELIG4CC
/GodPsnl by RELIG4CC BY MFCHATT4 .
* ------------------------- Appendix Table b: OLS separately
(Out of sequence because MISSING=PAIRWISE here).
SUBTITLE App Table B: Pooled .
REGRESSION VARIABLES= GodPsnl
MFCHATT4 Age male EducYr MFCATH
Relig4CC CommstCC GNP
/STATISTICS= R COEF /DESCRIPTIVES = DEFAULTS
/MISSING= PAIRWISE
/DEPENDENT= GodPsnl
/ENTER= MFCHATT4 Age male EducYr MFCATH
/ENTER= Relig4CC
/ENTER= CommstCC GNP .
SUBTITLE AppTblB: show nations in this order .
MEANS TABLES= GodPsnl BY Country.
SUBTITLE AppTbl B: EACH NATION SEPARATELY.
SPLIT FILE BY COUNTRY .
REGRESSION VARIABLES= GodPsnl
MFCHATT4 Age male EducYr MFCATH
/STATISTICS= R COEF /DESCRIPTIVES = DEFAULTS
/MISSING= PAIRWISE
/DEPENDENT= GodPsnl
/ENTER= MFCHATT4 Age male EducYr MFCATH .
SPLIT FILE OFF.
REGRESSION VARIABLES= GodPsnl
MFCHATT4 Age male EducYr MFCATH
Relig4CC CommstCC GNP USA RelXChAt
fChAtt2 , mChAtt2
/STATISTICS= R COEF /DESCRIPTIVES = DEFAULTS
/MISSING= LISTWISE
/DEPENDENT= GodPsnl
/ENTER= MFCHATT4 Age male EducYr MFCATH Relig4CC CommstCC GNP USA
/ENTER= RelXChAt .
* -------------------------- Text tables 4 - 6: NLR runs.
SELECT IF ( Miss EQ 0).
TITLE ISSP 1992: Relig MS (no missing data).
SUBTITLE : Table 4: MODEL A.
MODEL PROGRAM P=0.5
M1= 30 M2=50 m3=80 m4=90 m5=95
bage=.1 bmale=-.1 bcom=-.1 beduc=-.1 bgnp=0 bcath=0
BUSA=0 BNONCR=0 .
vector m = m1 to m5 .
COMPUTE PRED= P * M( RELIG4CC ) +
(1-P ) * M( MFCHATT4 ) +
bage*Age + bmale*male + bcom*CommstCC +beduc*EducYr +
BGNP*GNP + BCATH*MFCATH + BUSA*USA + BNONCR*MFNONCR .
NLR GodPsnl .
SUBTITLE: Table 4: MODEL B WITH INTERACTION FOR ROWS .
MODEL PROGRAM P1=0.5 P2=0.5 P3=0.5 P4=0.5 P5=0.5
M1= 30 M2=50 m3=80 m4=90 m5=95
bage=.1 bmale=-.1 bcom=-.1 beduc=-.1 bgnp=0 bcath=0
BUSA=0 BNONCR=0 .
VECTOR P = P1 TO P5 .
VECTOR M = M1 TO M5 .
COMPUTE PRED= P(RELIG4CC) * M( RELIG4CC ) +
(1-P(RELIG4CC)) * M( MFCHATT4 ) +
bage*Age + bmale*male + bcom*CommstCC +beduc*EducYr +
BGNP*GNP + BCATH*MFCATH + BUSA*USA + BNONCR*MFNONCR .
NLR GodPsnl .
SUBTITLE Table 4 & 6: Preferred MODEL C, W ROW23 & ROW45 .
MODEL PROGRAM P=0.5 DP23=0 DP45=0
M1= 30 M2=50 m3=80 m4=90 m5=95
bage=.1 bmale=-.1 bcom=-.1 beduc=-.1 bgnp=0 bcath=0
BUSA=0 BNONCR=0 .
vector m = m1 to m5 .
COMPUTE PRED= (P +DP23*ROW23+ DP45*ROW45) * M( RELIG4CC ) +
((1-P)-DP23*ROW23- DP45*ROW45) * M( MFCHATT4 ) +
bage*Age + bmale*male + bcom*CommstCC +beduc*EducYr +
BGNP*GNP + BCATH*MFCATH + BUSA*USA + BNONCR*MFNONCR .
NLR GodPsnl .
SUBTITLE Table 4: Model C + separate weight for parent catholic.
MODEL PROGRAM P=0.5 DP23=0 DP45=0
M1= 30 M2=50 m3=80 m4=90 m5=95
bage=.1 bmale=-.1 bcom=-.1 beduc=-.1 bgnp=0 bcath=0
BUSA=0 BNONCR=0
DSeprt =0.
vector m = m1 to m5 .
COMPUTE w = P +DP23*ROW23+ DP45*ROW45 + DSeprt* MFCATH .
COMPUTE PRED= w * M( RELIG4CC ) +
(1-w ) * M( MFCHATT4 ) +
bage*Age + bmale*male + bcom*CommstCC +beduc*EducYr +
BGNP*GNP + BCATH*MFCATH + BUSA*USA + BNONCR*MFNONCR .
NLR GodPsnl .
SUBTITLE Table 4: Model C + separate weight for age.
MODEL PROGRAM P=0.5 DP23=0 DP45=0
M1= 30 M2=50 m3=80 m4=90 m5=95
bage=.1 bmale=-.1 bcom=-.1 beduc=-.1 bgnp=0 bcath=0
BUSA=0 BNONCR=0
DSeprt =0.
vector m = m1 to m5 .
COMPUTE w = P +DP23*ROW23+ DP45*ROW45 + DSeprt* Age .
COMPUTE PRED= w * M( RELIG4CC ) +
(1-w ) * M( MFCHATT4 ) +
bage*Age + bmale*male + bcom*CommstCC +beduc*EducYr +
BGNP*GNP + BCATH*MFCATH + BUSA*USA + BNONCR*MFNONCR .
NLR GodPsnl .
SUBTITLE Table 4: Model C + separate weight for male.
MODEL PROGRAM P=0.5 DP23=0 DP45=0
M1= 30 M2=50 m3=80 m4=90 m5=95
bage=.1 bmale=-.1 bcom=-.1 beduc=-.1 bgnp=0 bcath=0
BUSA=0 BNONCR=0
DSeprt =0.
vector m = m1 to m5 .
COMPUTE w = P +DP23*ROW23+ DP45*ROW45 + DSeprt* Male.
COMPUTE PRED= w * M( RELIG4CC ) +
(1-w ) * M( MFCHATT4 ) +
bage*Age + bmale*male + bcom*CommstCC +beduc*EducYr +
BGNP*GNP + BCATH*MFCATH + BUSA*USA + BNONCR*MFNONCR .
NLR GodPsnl .
SUBTITLE Table 4: Model C + separate weight for education.
MODEL PROGRAM P=0.5 DP23=0 DP45=0
M1= 30 M2=50 m3=80 m4=90 m5=95
bage=.1 bmale=-.1 bcom=-.1 beduc=-.1 bgnp=0 bcath=0
BUSA=0 BNONCR=0
DSeprt =0.
vector m = m1 to m5 .
COMPUTE w = P +DP23*ROW23+ DP45*ROW45 + DSeprt* EducYr .
COMPUTE PRED= w * M( RELIG4CC ) +
(1-w ) * M( MFCHATT4 ) +
bage*Age + bmale*male + bcom*CommstCC +beduc*EducYr +
BGNP*GNP + BCATH*MFCATH + BUSA*USA + BNONCR*MFNONCR .
NLR GodPsnl .
SUBTITLE Table 4: Model C + separate weight for Communist society.
MODEL PROGRAM P=0.5 DP23=0 DP45=0
M1= 30 M2=50 m3=80 m4=90 m5=95
bage=.1 bmale=-.1 bcom=-.1 beduc=-.1 bgnp=0 bcath=0
BUSA=0 BNONCR=0
DSeprt =0.
vector m = m1 to m5 .
COMPUTE w = P +DP23*ROW23+ DP45*ROW45 + DSeprt* CommstCC .
COMPUTE PRED= w * M( RELIG4CC ) +
(1-w ) * M( MFCHATT4 ) +
bage*Age + bmale*male + bcom*CommstCC +beduc*EducYr +
BGNP*GNP + BCATH*MFCATH + BUSA*USA + BNONCR*MFNONCR .
NLR GodPsnl .
SUBTITLE Table 4: Model C + separate weight for GNP .
MODEL PROGRAM P=0.5 DP23=0 DP45=0
M1= 30 M2=50 m3=80 m4=90 m5=95
bage=.1 bmale=-.1 bcom=-.1 beduc=-.1 bgnp=0 bcath=0
BUSA=0 BNONCR=0
DSeprt =0.
vector m = m1 to m5 .
COMPUTE w = P +DP23*ROW23+ DP45*ROW45 + DSeprt* GNP .
COMPUTE PRED= w * M( RELIG4CC ) +
(1-w ) * M( MFCHATT4 ) +
bage*Age + bmale*male + bcom*CommstCC +beduc*EducYr +
BGNP*GNP + BCATH*MFCATH + BUSA*USA + BNONCR*MFNONCR .
NLR GodPsnl .
* ---------- end of text NLR tables.
*-------------------------------APP TABLE A: LOTS OF ALTERNATIVE MODELS! .
* --- Omit E Ger, Amer, Irish whose parents did not go to church.
SUBTITLE AppTbl A: No irrelig parents for US, NIre, EGers .
COMPUTE DUM=0.
IF ((RELIG4CC EQ 1) AND ((COUNTRY EQ 2)OR(COUNTRY EQ 4)OR(COUNTRY EQ 5)))
DUM=1.
TEMPORARY.
SELECT IF (DUM NE 1).
MODEL PROGRAM P=0.5 DP23=0 DP45=0
M1= 30 M2=50 m3=80 m4=90 m5=95
bage=.1 bmale=-.1 bcom=-.1 beduc=-.1 bgnp=0 bcath=0
BUSA=0 BNONCR=0 .
vector m = m1 to m5 .
COMPUTE PRED= (P +DP23*ROW23+ DP45*ROW45) * M( RELIG4CC ) +
((1-P)-DP23*ROW23- DP45*ROW45) * M( MFCHATT4 ) +
bage*Age + bmale*male + bcom*CommstCC +beduc*EducYr +
BGNP*GNP + BCATH*MFCATH + BUSA*USA + BNONCR*MFNONCR .
NLR GodPsnl .
* --- omit USA DUMMY.
SUBTITLE AppTbl A: OMIT USA Dummy.
MODEL PROGRAM P=0.5 DP23=0 DP45=0
M1= 30 M2=50 m3=80 m4=90 m5=95
bage=.1 bmale=-.1 bcom=-.1 beduc=-.1 bgnp=0 bcath=0
BNONCR=0 .
vector m = m1 to m5 .
COMPUTE PRED= (P +DP23*ROW23+ DP45*ROW45) * M( RELIG4CC ) +
((1-P)-DP23*ROW23- DP45*ROW45) * M( MFCHATT4 ) +
bage*Age + bmale*male + bcom*CommstCC +beduc*EducYr +
BGNP*GNP + BCATH*MFCATH + BNONCR*MFNONCR .
NLR GodPsnl .
* ^-------- app table A: runs with different country groupings!
Careful to restore the "usual" var afterwards .
*1st vsn; belief in God.
RECODE GodCC (1=1)(ELSE=0) INTO Row1 .
RECODE GodCC (2,3=1)(ELSE=0) INTO Row23 .
RECODE GodCC (4,5=1)(ELSE=0) INTO Row45 .
SUBTITLE App tbl A: rows based on belief in God only .
MODEL PROGRAM P=0.5 DP23=0 DP45=0
M1= 30 M2=50 m3=80 m4=90 m5=95
bage=.1 bmale=-.1 bcom=-.1 beduc=-.1 bgnp=0 bcath=0
BUSA=0 BNONCR=0 .
vector m = m1 to m5 .
COMPUTE PRED= (P +DP23*ROW23+ DP45*ROW45 ) * M( godcc ) +
((1-P)-DP23*ROW23- DP45*ROW45 ) * M( MFCHATT4 ) +
bage*Age + bmale*male + bcom*CommstCC +beduc*EducYr +
BGNP*GNP + BCATH*MFCATH + BUSA*USA + BNONCR*MFNONCR .
NLR GodPsnl .
*2nd vsn; Pnts chAtt (?careful about this one: it took more than 25
iterations to converge, compared to 6 to 10 for others, but the
parameters are fine and N Dirk is not worried!)
.
RECODE PChAttCC (1=1)(ELSE=0) INTO Row1 .
RECODE PChAttCC (4,5=1)(ELSE=0) INTO Row45 .
RECODE PChAttCC (2,3=1)(ELSE=0) INTO Row23 .
SUBTITLE App tbl A: rows based on belief in God only .
MODEL PROGRAM P=0.5 DP23=0 DP45=0
M1= 30 M2=50 m3=80 m4=90 m5=95
bage=.1 bmale=-.1 bcom=-.1 beduc=-.1 bgnp=0 bcath=0
BUSA=0 BNONCR=0 .
vector m = m1 to m5 .
COMPUTE PRED= (P +DP23*ROW23+ DP45*ROW45 ) * M( PChAttCC ) +
((1-P)-DP23*ROW23- DP45*ROW45 ) * M( MFCHATT4 ) +
bage*Age + bmale*male + bcom*CommstCC +beduc*EducYr +
BGNP*GNP + BCATH*MFCATH + BUSA*USA + BNONCR*MFNONCR .
NLR GodPsnl .
*3d: restore original rows.
RECODE RELIG4CC (1=1)(ELSE=0) INTO Row1 .
RECODE RELIG4CC (4,5=1)(ELSE=0) INTO Row45 .
RECODE RELIG4CC (2,3=1)(ELSE=0) INTO Row23 .
* ------ preferred model, equal weighting of nations.
weight by EqualWt .
SUBTITLE AppTblA: EQUAL WTS, Preferred MODEL C .
MODEL PROGRAM P=0.5 DP23=0 DP45=0
M1= 30 M2=50 m3=80 m4=90 m5=95
bage=.1 bmale=-.1 bcom=-.1 beduc=-.1 bgnp=0 bcath=0
BUSA=0 BNONCR=0 .
vector m = m1 to m5 .
COMPUTE PRED= (P +DP23*ROW23+ DP45*ROW45) * M( RELIG4CC ) +
((1-P)-DP23*ROW23- DP45*ROW45) * M( MFCHATT4 ) +
bage*Age + bmale*male + bcom*CommstCC +beduc*EducYr +
BGNP*GNP + BCATH*MFCATH + BUSA*USA + BNONCR*MFNONCR .
NLR GodPsnl .
WEIGHT OFF.
* --------------- end of Appendix Table A runs.
* --------------------- model without devout people & religious nations --
re firebaugh's "ceiling" argument; Niemegen Jan 97! .
TEMPORARY.
SELECT IF ( Miss EQ 0) AND (relig4cc ne 5) AND (mfchatt4 ne 5).
SUBTITLE Model C, excluding the most devout psns & nations .
MODEL PROGRAM P=0.5 DP23=0 DP45=0
M1= 30 M2=50 m3=80 m4=90
bage=.1 bmale=-.1 bcom=-.1 beduc=-.1 bgnp=0 bcath=0
BUSA=0 BNONCR=0 .
vector m = m1 to m4 .
COMPUTE PRED= (P +DP23*ROW23+ DP45*ROW45) * M( RELIG4CC ) +
((1-P)-DP23*ROW23- DP45*ROW45) * M( MFCHATT4 ) +
bage*Age + bmale*male + bcom*CommstCC +beduc*EducYr +
BGNP*GNP + BCATH*MFCATH + BUSA*USA + BNONCR*MFNONCR .
NLR GodPsnl .
* ^----------------------------------------------------------------- END.